home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 56 / 64er_Magazin_Sonderheft_56_19xx_Markt__Technik_de_Side_B.d64 / knobelaufgabe 3 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  16KB  |  431 lines
  1. 10 rem"  [213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]
  2. 11 [143]"  peek                            peek
  3. 12 rem"  [194] knobelaufgabe 3            [194]
  4. 13 [143]"  peek                            peek
  5. 14 rem"  [194] aus 64'er sonderheft 47    [194]
  6. 15 [143]"  -lenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlen<
  7. 16 rem"  [194]                            [194]
  8. 17 [143]"  peek      manfred werner        peek
  9. 18 rem"  [194]      zimmermannstr. 27     [194]
  10. 19 [143]"  peek      1000 berlin 41        peek
  11. 20 rem"  [194]                            [194]
  12. 21 [143]"  peek      1990                  peek
  13. 22 rem"  [194]                            [194]
  14. 23 [143]"  mid$lenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlenlen(NULL)
  15. 24 rem"
  16. 25 [143]"
  17. 100 goto 550
  18. 104 rem ------------------------------
  19. 105 print " [146][157]";
  20. 106 get c$: if c$="" goto 106
  21. 107 c=asc(c$): print " [157]";: return
  22. 109 rem ------------------------------
  23. 110 gosub 105: e=-(c=17)-2*(c=145):                    e=e-3*(c=157)-4*(c=133)
  24. 111 if e>0 then print " [157]";
  25. 112 return
  26. 114 rem ------------------------------
  27. 115 gosub 105:                              if c=13 then print " [157]";: return
  28. 116 goto 115
  29. 159 rem ------------------------------
  30. 160 x$="": xl=0
  31. 170 gosub 110: if e>0 then return
  32. 171 if g and f goto 202
  33. 175 if f1 and xl=0 and (c=63) then g=-1:       print c$;:x$=x$+c$:xl=1:goto170
  34. 180 al=c>64 and c<91: za=c>47 and c<58
  35. 190 if (al or za) and xl<4 then                print c$;: x$=x$+c$: xl=xl+1
  36. 200 if xl=0 goto 170
  37. 202 if c<>20 goto 214
  38. 204 print " [157][157]";: xl=xl-1:                  x$=left$(x$,xl): g=0: goto 170
  39. 214 if c<>z1 and c<>z2 goto 170
  40. 215 print c$;: z1=c+1-(c=91): z2=z1
  41. 216 if xl=4 then return
  42. 217 x$=x$+" ": xl=xl+1: goto 216
  43. 219 rem -------------------------------
  44. 220 for m=1 to h:                           p%(k,m,1)=val(mid$(a$(k),11+m,1))
  45. 221 if p%(k,m,1)=0 then m=m-1: goto 223
  46. 222 next m
  47. 223 z%(k)=m: f%(k)=5:if m=1 then f%(k)=1
  48. 224 return
  49. 225 rem -------------------------------
  50. 226 for m=1 to h-1:                             p%(k,m,1)=m: p%(k,m,2)=m+1
  51. 227 next m: z%(k)=h-1: f%(k)=2: return
  52. 229 rem -------------------------------
  53. 230 for m=1 to h-1:                             p%(k,m,1)=m+1: p%(k,m,2)=m
  54. 231 next m: z%(k)=h-1: f%(k)=2: return
  55. 234 rem -------------------------------
  56. 235 for m=1 to h:                               p%(k,m,1)=m: p%(k,m,2)=m
  57. 236 next m:z%(k)=h: if c=0 then f%(k)=7:    return
  58. 237 kl$=mid$(a$(k),16,1):                   if kl$="[" then f%(k)=6: return
  59. 238 f%(k)=2: return
  60. 239 rem -------------------------------
  61. 240 for m1=1 to h-2
  62. 241 :   for m2=1 to 2: m=2*m1+m2-2:                 p%(k,m,1)=m1+1
  63. 242 :       p%(k,m,2)=m1-2+2*m2:                    p%(k,m,3)=m1+4-2*m2
  64. 243 next m2,m1: z%(k)=2*(h-2): f%(k)=3:     return
  65. 244 rem -------------------------------
  66. 245 for m1=1 to h-1:                            for m2=1 to 2: m=2*m1+m2-2
  67. 246 :       p%(k,m,1)=m1+m2-1:                      p%(k,m,2)=m1-m2+2
  68. 247 next m2,m1: z%(k)=2*(h-1): f%(k)=4:     return
  69. 249 rem -------------------------------
  70. 280 for i=1 to an: a$(i)="": next i
  71. 281 for i=1 to r: bn%(i)=0: r$(i)="":       for j=1 to h: i%(j,i)=0: b$(j,i)=""
  72. 282 next j,i: rn=0: return
  73. 329 rem -------------------------------
  74. 330 n%(i)=n%(n1):n%(n1)=ih:n1=n1+1:         return
  75. 334 rem -------------------------------
  76. 335 n%(k)=n%(n1):n%(n1)=kh:n1=n1+1:         return
  77. 359 rem -------------------------------
  78. 360 for i=1 to h:                              if i%(i,r%(n,2))=b%(n,2) goto 362
  79. 361 next i
  80. 362 a$=a$(n): r0=r%(n,1): i0=i%(i,r0)
  81. 363 a$(n)=left$(a$,5)+""+b$(i0,r0)               +"[146]"+right$(a$,12): return
  82. 364 rem ------------------------------
  83. 365 for i=1 to h:                              if i%(i,r%(n,1))=b%(n,1) goto 367
  84. 366 next i
  85. 367 r0=r%(n,2)
  86. 368 a$(n)=left$(a$(n),16)+""                     +b$(i%(i,r0),r0)+"[146])": return
  87. 369 rem ------------------------------
  88. 370 for i=1 to h:                              if i%(i,r%(n,1))=b%(n,1) goto 372
  89. 371 next i
  90. 372 a$(n)=left$(a$(n),11)+""+str$(i)             +"[146]": return
  91. 374 rem -------------------------------
  92. 375 a$=a$(n):r0=r%(n,1):i0=i%(l%(n),r0)
  93. 376 a$(n)=left$(a$,5)+""+b$(i0,r0)               +"[146]"+right$(a$,3)
  94. 377 return
  95. 404 rem -------------------------------
  96. 405 for i=2 to x: t$=t$+t0$: next i:        t$=t$+x$: print t$: return
  97. 434 rem -------------------------------
  98. 435 z=21:s=1: m$=le$: gosub 440: m$=m0$
  99. 439 z=21: s=1
  100. 440 poke 214,z: poke 211,s: sys 58640:      print m$;: return
  101. 459 rem -------------------------------
  102. 460 r0=r%(n,h0): b0=b%(n,h0):               p1=v%(n,vn%(n)): p0=p%(n,p1,h0)
  103. 461 i%(p0,r0)=b0: return
  104. 469 rem -------------------------------
  105. 470 for i=1 to 3:                               h0=h%(n,i): if h0=0 goto 474
  106. 471 :   r0=r%(n,h0): p1=v%(n,vn%(n)):           p0=p%(n,p1,h0)
  107. 472 :   i%(p0,r0)=0
  108. 474 next i: return
  109. 489 rem -------------------------------
  110. 490 c$=mid$(a$,i,1): c=asc(c$+chr$(0)):     if c=32 then i=i+1: goto 490
  111. 495 i=i+1: return
  112. 499 rem -------------------------------
  113. 500 x$="": xl=0
  114. 501 gosub 490:                              if c<>63 then f=0: goto 512
  115. 502 gosub 490:                              if c<>z1 and c<>z2 then e=-1: return
  116. 503 a0$=a0$+"?   )": f=-1: goto 517
  117. 510 x$="": xl=0
  118. 511 gosub 490
  119. 512 zb=c>64 and c<91 or c>47 and c<58
  120. 513 if zb then x$=x$+c$:xl=xl+1:goto 511
  121. 514 if c<>z1 and c<>z2 or xl=0 then            e=-1: return
  122. 515 if xl<4 then x$=x$+" ": xl=xl+1:           goto 515
  123. 516 x$=left$(x$,4): a0$=a0$+x$+c$
  124. 517 m$=str$(k)+" "+a0$: gosub 439:          e=0: return
  125. 549 rem -------------------------------
  126. 550 t0$="[195]": t1$="[213]": t2$="[201]": t3$="[202]":     t4$="[203]": t5$="[194]": t6$="[171]": t7$="[179]"
  127. 551 t8$="[195][195][195][195]"
  128. 552 le$="                                     "
  129. 558 poke 53280,6: poke 53281,6
  130. 559 rem -------------------------------
  131. 560 dim a$(60),i%(7,8),b$(7,8),r$(8),           bn%(8),p%(60,12,3)
  132. 561 dim z%(60),jn%(60),l%(60),f%(60),           n%(60),ma%(60),mb%(60),v%(60,12)
  133. 562 dim vn%(60),vm%(60),v1%(60),v2%(60),        r%(60,3),b%(60,3),h%(60,3)
  134. 599 rem -------------------------------
  135. 600 t$="[147][213]": x=30: x$=t2$: gosub 405
  136. 610 t$=   "[194] l o g i c a l   ":             t$=t$+"b r i c k s [194]": print t$
  137. 620 t$=t3$: x$=t4$: gosub 405
  138. 640 poke 214,20: poke 211,0: sys 58640
  139. 650 t$=t1$: x=38: x$=t2$: gosub 405
  140. 670 t$=   "[194]                                     [194]": print t$
  141. 680 t$=t3$: x$=t4$: gosub 405: goto 810
  142. 699 rem -------------------------------
  143. 700 m0$="einheiten: ?[146][157]": gosub 435
  144. 710 get c$: if c$="" goto 710
  145. 720 h=asc(c$)-48:if h<2 or h>7 goto 710
  146. 730 print c$+" rubriken: ?[146][157]";
  147. 740 get c$: if c$="" goto 740
  148. 750 r=asc(c$)-48:if r<2 or r>8 goto 740
  149. 761 print c$+" aussagen: ?[146][157]";
  150. 762 get c$: if c$="" goto 762
  151. 763 print c$;: a1=asc(c$)-48:               if a1<0 or a1>9 goto 762
  152. 764 print "?[146][157]";: get c$:                  if c$="" goto 764
  153. 765 print c$;: a0=asc(c$)-48:               if a0<0 or a0>9 goto 764
  154. 766 an=a0+10*a1: if an<10 or an>60 then        print "[157] [157][157]?[146][157]";: goto 762
  155. 767 goto 985
  156. 769 rem -------------------------------
  157. 810 m0$="aussagen als daten lesen ":        gosub 435
  158. 811 gosub 105:                              on -(c=17)-2*(c=13) goto 813,900
  159. 812 goto 811
  160. 813 m0$="aussagen-editor ": gosub 435
  161. 814 gosub 105:                              on -(c=17)-2*(c=13) goto 810,700
  162. 815 goto 814
  163. 899 rem -------------------------------
  164. 900 read h,r,an
  165. 901 for i=1 to an: read a$(i): next i
  166. 910 m0$="syntax-test": gosub 435
  167. 915 for k=1 to an: a$=a$(k):                    if a$="" goto 930
  168. 920 :   gosub 1102
  169. 925 :   if e then m0$="syntax-fehler":             gosub 435:gosub 105: goto 990
  170. 926 :   a$(k)=a0$
  171. 930 next k: goto 2000
  172. 984 rem ------aussageneditor-----------
  173. 985 k=1
  174. 990 a$(k)="": f=0
  175. 994 a$=a$(k): al=len(a$)
  176. 995 m0$=str$(k)+" "+a$: gosub 435: ae=0
  177. 1000 gosub 105:                              on -(c<32)-2*(c>95) goto 1020,1025
  178. 1005 if al=33 goto 1000
  179. 1010 print c$;: a$=a$+c$: al=al+1:           ae=-1: goto 1000
  180. 1020 on -(c=13)-2*(c=17)-3*(c=20)               goto 1100,1045,1035
  181. 1021 goto 1000
  182. 1025 on -(c=133)-2*(c=145)-3*(c=157)            goto 1200,1055,990
  183. 1030 goto 1000
  184. 1035 if al=0 goto 1000
  185. 1040 print " [157][157]";: al=al-1: ae=-1:           a$=left$(a$,al): goto 1000
  186. 1045 if ae then a$(k)=""
  187. 1046 k=k+1: if k>an then k=1
  188. 1050 goto 994
  189. 1055 if ae then a$(k)=""
  190. 1056 k=k-1: if k=0 then k=an
  191. 1060 goto 994
  192. 1100 if a$="" goto 1000
  193. 1101 gosub 1102: goto 1190
  194. 1102 i=1: a0$="": m$=le$: gosub 439
  195. 1103 z1=40: z2=z1: gosub 510:                if e then return
  196. 1105 z1=41: z2=z1: gosub 500:                if e then return
  197. 1110 gosub 490: o=c:                         on -(c=43)-2*(c=61) goto 1150,1175
  198. 1120 if f then e=-1: return
  199. 1125 on -(c=0)-2*(c=60 or c=62 or c=35)         -3*(c=58) goto 1130,1150,1135
  200. 1130 e=0: return
  201. 1135 a0$=a0$+c$: z1=40: z2=z1:               gosub 510 : if e then return
  202. 1140 z1=41: z2=z1: gosub 510:                if e then return
  203. 1145 gosub 490:                              if c<>44 then e=0: return
  204. 1150 a0$=a0$+c$: z1=40:                      z2=z1-51*(not f and o=43)
  205. 1151 gosub 510: if e then return
  206. 1155 z1=c-(c=91)+1: z2=z1:                   on 1-(z1=93 or f) gosub 500,510
  207. 1160 if e then return
  208. 1165 gosub 490:                              if c<>0 then e=-1: return
  209. 1170 e=0: return
  210. 1175 a0$=a0$+c$: c1=0
  211. 1176 gosub 490
  212. 1178 if c>48 and c<(49+h) and c>c1 then         a0$=a0$+c$: c1=c: goto 1176
  213. 1180 if f or c1>0 goto 1184
  214. 1182 if c=63 then a0$=a0$+c$: gosub 490
  215. 1184 gosub 517: e=(c<>0): return
  216. 1190 if e then m0$="syntax-fehler":             gosub 435: gosub 105: goto 990
  217. 1195 a$(k)=a0$: goto 1046
  218. 1999 rem -----aussagencodierung--------
  219. 2000 m0$="codieren ": gosub 435:             gosub 115: kn=0: km=an+1
  220. 2005 for k=1 to an: a$=a$(k): y1=-1:             c$=mid$(a$,12,1): y2=(c$<>"?")
  221. 2010 :   if a$="" goto 2220
  222. 2020 :   o$=mid$(a$,11,1)
  223. 2021 :   c=asc(o$+chr$(0))
  224. 2030 :   j=-(c=43 or c=60 or c=62 or               c=35)-2*(c=58): jn%(k)=j+1
  225. 2031 :   on -(c=0 or c=43)-2*(c=61)                 gosub 235,220
  226. 2032 :   on -(c=60)-2*(c=62)-3*(c=35)               gosub 225,230,245
  227. 2033 :   if c=58 then gosub 240
  228. 2040 :   for i=0 to j: p=11*i+1:                 :   r$=mid$(a$,p,4)
  229. 2050 :       for i1=0 to rn
  230. 2051 :           if r$=r$(i1) then                       r%(k,i+1)=i1: goto 2120
  231. 2060 :       next i1
  232. 2070 :       rn=rn+1:if rn<=r goto 2110
  233. 2080 :       m1$="zu viele rubriken":                goto 2250
  234. 2110 :       r$(rn)=r$: r%(k,i+1)=rn
  235. 2120 :       b$=mid$(a$,p+5,4)
  236. 2121 :      if b$="?   " then f%(k)=i+1:               y1=0: goto 2210
  237. 2129 :       for j1=0 to bn%(i1)
  238. 2130 :       if b$=b$(j1,i1) then                       b%(k,i+1)=j1: goto 2210
  239. 2140 :       next j1
  240. 2150 :       bn%(i1)=bn%(i1)+1:                      if bn%(i1)<=h goto 2190
  241. 2160 :       m1$="zu viele begriffe/":               m1$=m1$+"rubr"
  242. 2170 :       goto 2250
  243. 2190 :       b$(bn%(i1),i1)=b$:                      b%(k,i+1)=bn%(i1)
  244. 2210 :   next i
  245. 2211 :   if y1 and y2 then kn=kn+1:                 n%(kn)=k: goto 2220
  246. 2212 :   if o$="=" then f%(k)=3-y2:                 l%(k)=val(c$)
  247. 2213 :   km=km-1: n%(km)=k
  248. 2220 next k
  249. 2229 e1=-1
  250. 2230 for i1=1 to r:                              e1=(bn%(i1)=h) and e1
  251. 2240 next i1: if e1 and rn=r goto 3000
  252. 2245 m1$="zu wenige begriffe"
  253. 2250 m0$=m1$+" - korrektur ": gosub 435
  254. 2251 gosub 105:                              on -(c=17)-2*(c=13) goto 2253,2260
  255. 2252 goto 2251
  256. 2253 m0$=m1$+" - abbruch ": gosub 435
  257. 2254 gosub 105:                              on -(c=17)-2*(c=13) goto 2250,5000
  258. 2255 goto 2254
  259. 2260 gosub 290:gosub 281: goto 994
  260. 2999 rem --------ordnen 1/2------------
  261. 3000 m0$="aufgabe loesen ": gosub 435:       k0=kn: n0=1: k=1
  262. 3010 oa=0: ob=0: ua=kn+1: ub=kn+1
  263. 3015 n=n%(k): on f%(n) goto                  3020,3080,3040,3045,3065,3050,3055
  264. 3020 r0=r%(n,1):b0=b%(n,1):p0=p%(n,1,1)
  265. 3021 if i%(p0,r0)=b0 goto 3060
  266. 3025 if i%(p0,r0)<>0 goto 4990
  267. 3030 for p1=1 to h:                              if i%(p1,r0)=b0 goto 4990
  268. 3035 next p1: gosub 461: goto 3120
  269. 3040 oa=oa+1: ma%(oa)=n: goto 3060
  270. 3045 ua=ua-1: ma%(ua)=n: goto 3060
  271. 3050 ob=ob+1: mb%(ob)=n: goto 3060
  272. 3055 ub=ub-1: mb%(ub)=n
  273. 3060 n%(k)=n%(k0): k0=k0-1: goto 3067
  274. 3065 n%(k)=n%(n0): n%(n0)=n: n0=n0+1
  275. 3066 k=k+1
  276. 3067 if k<=k0 goto 3015
  277. 3068 goto 3130
  278. 3080 for l=1 to 2
  279. 3081 for p1=1 to z%(n)
  280. 3085 : if i%(p%(n,p1,l),r%(n,l))=b%(n,l)          goto 3095
  281. 3090 next p1,l: goto 3066
  282. 3095 r0=r%(n,3-l): b0=b%(n,3-l):             p0=p%(n,p1,3-l)
  283. 3100 if i%(p0,r0)=b0 goto 3120
  284. 3105 if i%(p0,r0)<>0 goto 4990
  285. 3110 for p2=1 to h:                              if i%(p2,r0)=b0 goto 4990
  286. 3115 next p2: gosub 461
  287. 3120 n%(k)=n%(k0):k0=k0-1:k=n0:goto 3015
  288. 3130 k2=k0: if oa=0 goto 3136
  289. 3135 for i=1 to oa:n%(k0+i)=ma%(i):next:     k2=k0+oa
  290. 3136 if ua=kn+1 goto 3150
  291. 3140 for i=1 to kn-ua+1:                         n%(k2+i)=ma%(ua+i-1)
  292. 3145 next i: k2=k2+kn-ua+1
  293. 3150 k1=k2: if ob=0 goto 3400
  294. 3155 for i=1 to ob:n%(k1+i)=mb%(i):next:     k1=k1+ob
  295. 3399 rem ------ordnen 3/4--------------
  296. 3400 n0=1: k=k0+1: q=0: goto 3405
  297. 3401 if k>n0 then n%(k)=n%(n0):n%(n0)=n
  298. 3403 n0=n0+1
  299. 3404 k=n0
  300. 3405 if k<=k2 goto 3510
  301. 3406 if q goto 4500
  302. 3407 q=-1: k=n0
  303. 3510 n=n%(k)
  304. 3525 for l=1 to jn%(n)
  305. 3526 :   for p1=1 to h
  306. 3527 :       if i%(p1,r%(n,l))=b%(n,l)                  goto 3534
  307. 3528 :   next p1
  308. 3529 next l: if not q then k=k+1:                       goto 3405
  309. 3530 vn=0: h%(n,1)=1
  310. 3531 for p2=1 to z%(n)
  311. 3532 :   if i%(p%(n,p2,1),r%(n,1))=0                then vn=vn+1: v%(n,vn)=p2
  312. 3533 next p2: l%(n)=1: goto 3543
  313. 3534 vn=0: h%(n,1)=0
  314. 3535 for p2=1 to z%(n)
  315. 3536 :   if p%(n,p2,l)=p1 then vn=vn+1:             v%(n,vn)=p2
  316. 3537 next p2: if vn=0 goto 3640
  317. 3542 l%(n)=l
  318. 3543 vn%(n)=1: v1%(n)=vn
  319. 3545 if h%(n,1)=1 then h0=1: gosub 460
  320. 3546 if jn%(n)=1 goto 3401
  321. 3547 h%(n,2)=0: h%(n,3)=0
  322. 3549 if jn%(n)=3 goto 3570
  323. 3550 l1=3-l%(n):r0=r%(n,l1):b0=b%(n,l1):     p1=v%(n,vn%(n)): p0=p%(n,p1,l1)
  324. 3555 if i%(p0,r0)=b0 goto 3401
  325. 3560 if i%(p0,r0)<>0 goto 3630
  326. 3565 for p2=1 to h:                              if i%(p2,r0)=b0 goto 3630
  327. 3567 next p2: h%(n,2)=l1: h0=l1:             gosub 460: goto 3401
  328. 3570 l1=1: if l%(n)=1 then l1=2
  329. 3571 r0=r%(n,l1): b0=b%(n,l1):               p1=v%(n,vn%(n)): p0=p%(n,p1,l1)
  330. 3575 if i%(p0,r0)=b0 goto 3590
  331. 3580 if i%(p0,r0)<>0 goto 3630
  332. 3585 for p2=1 to h:                              if i%(p2,r0)=b0 goto 3630
  333. 3587 next p2: h%(n,2)=l1: h0=l1:             gosub 460
  334. 3590 l2=6-l%(n)-l1
  335. 3591 r0=r%(n,l2): b0=b%(n,l2):               p0=p%(n,p1,l2)
  336. 3600 if i%(p0,r0)=b0 goto 3401
  337. 3605 if i%(p0,r0)<>0 goto 3630
  338. 3610 for p2=1 to h:                              if i%(p2,r0)=b0 goto 3630
  339. 3620 next p2: h%(n,3)=l2: h0=l2:             gosub 460: goto 3401
  340. 3630 gosub 470
  341. 3640 vn%(n)=vn%(n)+1
  342. 3641 if vn%(n)<=v1%(n) goto 3545
  343. 3645 n0=n0-1: if n0=0 goto 4990
  344. 3646 n=n%(n0):gosub 470:vn%(n)=vn%(n)+1
  345. 3648 if vn%(n)>v1%(n) goto 3645
  346. 3650 k=n0: goto 3545
  347. 4499 rem ---------ordnen 5-------------
  348. 4500 k=k2
  349. 4505 k=k+1: n=n%(k): if k>k1 goto 4800
  350. 4510 h%(n,1)=0: h%(n,2)=0: h%(n,3)=0:        v1%(n)=0: v2%(n)=0
  351. 4515 for p0=1 to h: b0=i%(p0,r%(n,1))
  352. 4520 :  if b0=b%(n,1) then p%(n,1,1)=p0:           v1%(n)=1: goto 4535
  353. 4525 :   if b0=0 then v1%(n)=v1%(n)+1:              p%(n,v1%(n),1)=p0
  354. 4530 next p0
  355. 4535 for p0=1 to h: b0=i%(p0,r%(n,2))
  356. 4540 :  if b0=b%(n,2) then p%(n,1,2)=p0:           v2%(n)=1: goto 4560
  357. 4550 :   if b0=0 then v2%(n)=v2%(n)+1:              p%(n,v2%(n),2)=p0
  358. 4555 next p0
  359. 4560 if v1%(n)=0 or v2%(n)=0 goto 4610
  360. 4565 vn%(n)=1
  361. 4570 p1=p%(n,vn%(n),1): vm%(n)=1
  362. 4575 p2=p%(n,vm%(n),2):                      if p1=p2 goto 4600
  363. 4580 b0=b%(n,1): r0=r%(n,1): p0=p1
  364. 4581 if i%(p0,r0)=0 then h%(n,1)=1:          gosub 461
  365. 4585 b0=b%(n,2): r0=r%(n,2): p0=p2
  366. 4586 if i%(p0,r0)=0 then h%(n,2)=2:          gosub 461
  367. 4590 goto 4505
  368. 4600 vm%(n)=vm%(n)+1:                        if vm%(n)<=v2%(n) goto 4575
  369. 4605 vn%(n)=vn%(n)+1:                        if vn%(n)<=v1%(n) goto 4570
  370. 4610 k=k-1: n=n%(k): if k<=k2 goto 3640
  371. 4615 gosub 470
  372. 4620 vm%(n)=vm%(n)+1:                        if vm%(n)>v2%(n) goto 4630
  373. 4625 goto 4575
  374. 4630 vn%(n)=vn%(n)+1:                        if vn%(n)>v1%(n) goto 4610
  375. 4635 goto 4570
  376. 4799 rem --------ordnen 6--------------
  377. 4800 k=ub
  378. 4801 if k>kn goto 4900
  379. 4802 n=mb%(k): r0=r%(n,1): b0=b%(n,1)
  380. 4805 for p0=1 to h
  381. 4806 :   if i%(p0,r0)=0 then gosub 461:             goto 4820
  382. 4807 :   if i%(p0,r0)=b0 goto 4820
  383. 4810 next p0: goto 4990
  384. 4820 k=k+1: goto 4801
  385. 4899 rem ------------------------------
  386. 4900 if km=an+1 goto 5100
  387. 4910 m0$="loesung ": gosub 435: z=2: s=1
  388. 4916 for k=km to an: n=n%(k):                    on f%(n) gosub 360,365,370,375
  389. 4918 :   z=z+2: m$=a$(n): gosub 440
  390. 4920 next k: goto 5100
  391. 4989 rem ------------------------------
  392. 4990 m1$="widerspruch: aussage"+str$(n):     goto 2250
  393. 4999 rem ------------------------------
  394. 5100 poke 214,22: sys 58640: end
  395. 5105 poke 214,22: sys 58640: end
  396. 8999 rem ------------------------------
  397. 9000 data 6,5,32
  398. 9001 data "name(elm)+tier(kein)"
  399. 9002 data "spei(supp)+hobb(les)"
  400. 9003 data "name(har):name(andy),name(elm)"
  401. 9004 data "hobb(auto)+spei[kuch]"
  402. 9005 data "haar(brau)=6"
  403. 9006 data "haar(kein)=2456"
  404. 9007 data "haar(schw)>name(nick)"
  405. 9008 data "tier(aal)+spei[fish]"
  406. 9009 data "tier(katz):haar(schw),haar(grau)"
  407. 9010 data "haar(grau)#hobb(prog)"
  408. 9011 data "name(elm)#name(nick)"
  409. 9012 data "name(stef)=135"
  410. 9013 data "name(stef)+spei(sal)"
  411. 9014 data "name(elm)+spei(stek)"
  412. 9015 data "tier(pfer)=23456"
  413. 9016 data "name(andy)+haar(grau)"
  414. 9017 data "name(nick)+haar[rot]"
  415. 9018 data "tier(katz)+spei(supp)"
  416. 9019 data "haar(rot)#hobb(tv)"
  417. 9020 data "haar(grau)<tier(hund)"
  418. 9021 data "name(nick)=1"
  419. 9022 data "tier(katz)>haar(schw)"
  420. 9023 data "hobb(bast)+haar(grau)"
  421. 9024 data "tier(vog)+hobb(koch)"
  422. 9025 data "tier(katz)#tier(aal)"
  423. 9026 data "haar(blon)+spei(pomm)"
  424. 9027 data "name(gott)"
  425. 9028 data "name(gott)=?"
  426. 9029 data "name(andy)+tier(?)"
  427. 9030 data "name(nick)+haar(?)"
  428. 9031 data "name(?)+spei(kuch)"
  429. 9032 data "name(?)+hobb(auto)"
  430. 9099 rem ------------------------------
  431.